Модуль 16-битного АЦП ADS1115
Нередко в радиолюбительской практике возникает необходимость измерить напряжение на каком-либо участке цепи с последующей оцифровкой и анализом полученного результата.
Содержание
Обзор
Нередко в радиолюбительской практике возникает необходимость измерить напряжение на каком-либо участке цепи с последующей оцифровкой и анализом полученного результата. Для этих целей используют аналогово-цифровые преобразователи, которые переводят величину напряжения в его числовой эквивалент, понятный микроконтроллеру.
Все кто когда-либо работал с платформами Arduino, наверняка знают, что она оснащена 10-битным аналогово-цифровым преобразователем (АЦП), подключенным к пинам A0-A7 в качестве альтернативной функции портов ввода/вывода. Но зачастую возможностей этого АЦП не хватает, когда точность, скорость и гибкость измерений критична для конкретного проекта.
Модуль 16-битного АЦП ADS1115 лишён вышеперечисленных недостатков. Помимо этого он имеет внутренний источник опорного напряжения, программируемую частоту дискретизации, настраиваемый коэффициент усиления, встроенный компаратор и возможность выполнять измерения в 2-х режимах, прямом и дифференциальном. Внешний вид модуля показан на рисунке №1.
Рисунок №1 – внешний вид модуля ADS1115
Как видно из вышеприведенного рисунка, модуль содержит 10 выводов, краткое описание которых представлено ниже:
VDD и GND отвечают за питание микросхемы ADS1115. Модуль может работать в диапазоне от 2В до 5.5В.
Наличие выводов SCL и SDA говорит о том, что модуль общается с ведущим устройством по протоколу I2C. Дополнительно устанавливать подтягивающие резисторы на шину нет необходимости, так как они уже предусмотрены в конструкции модуля.
ARRD – задаёт один из 4-х возможных адресов модуля. Данная функция имеет смысл при использовании нескольких ADS1115 на одной шине I2C.
ALRT – выход компаратора, который удобно использовать для оповещения управляющего устройства.
A0, A1, A2, A3 – входы АЦП, которые могут быть настроены как 4 одиночных канала или 2 дифференциальных. В последнем случае появляется возможность измерять разность потенциалов между выводами A0-A1 и A2-A3.
На рисунке №2 представлена электрическая схема модуля ADS1115.
Рисунок №2 – электрическая схема модуля ADS1115
Конденсаторы С1 и C2 предназначены для устранения помех в цепи питания микросхемы АЦП. Резистор R1 подтягивает выход компаратора к низкому уровню. Следовательно, сигнал оповещения будет эквивалентен логической единице. Резисторы R2 и R3 подтягивают I2C шину до уровня питания, что освобождает пользователя от применения внешних сопротивлений.
Как упоминалось ранее, модуль ADS1115 может иметь один из 4-х возможных адресов в зависимости от того, куда подключен вывод ADDR. Из схемы видно, что он притянут резистором R4 к минусу питания, что по умолчанию присваивает модулю адрес 0x48. Для изменения адреса, вывод ADDR подключают по одному из вариантов, приведённых на рисунке №3.
Рисунок №3 – варианты выбора адреса ADS1115
Исходя из вышеизложенного, можно сделать вывод, что на одной шине I2C могут присутствовать одновременно 4 модуля ADS1115. Этого более чем достаточно для большинства микроконтроллерных проектов, учитывая то, что каждый модуль имеет по несколько каналов.
В целом, каждая микросхема ADS1115 имеет в своём составе 4 аналоговых входа (А0, А1, А2, А3). В зависимости от настроек, эти входы могут использоваться как 4 одиночных канала измерения или как 2 дифференциальных. В дифференциальном режиме напряжение меряется между входами А0-А1 и А2-А3. На рисунке №4 показана внутренняя структура микросхемы ADS1115.
Рисунок №4 – структурная схема чипа ADS1115
Глядя на схему, можно сделать вывод, что необходимая конфигурация аналоговых входов настраивается с помощью внутреннего мультиплексора, условно обозначенного как контакты реле. В каждый момент времени относительно внутреннего АЦП AINp и AINn может быть выставлена только одна определённая конфигурация.
В случае использования дифференциального режима, действует одно правило: при AINp>AINn напряжение определяется как положительное, а если AINp<AINn – напряжение будет отрицательным.
Если же выставлен режим одиночных (несимметричных) входов, то измерения будут производиться исключительно между положительным входным сигналом и общим проводом ADS1115. В данном режиме измерить отрицательное напряжение не представляется возможным.
Вне зависимости от выбранного режима, после поступления входного сигнала в измерительный тракт АЦП, у пользователя появляется возможность усилить его посредствам встроенного аппаратного усилителя PGA с разными коэффициентами усиления. Всего доступно 6 уровней масштабирования. Каждый из них задаёт верхний предел измеряемого напряжения, выходить за рамки которого строго не рекомендуется. То же самое касается и напряжения питания модуля – оно должно быть равно или больше максимального предела измерений. Ниже приведена таблица, которая отражает оговоренную выше зависимость.
|
№п/п |
Коэффициент усиления |
Предел измерения |
Значимость одного бита |
|
1 |
2/3 |
±6,144V |
1 бит = 0,1875mV |
|
2 |
1 |
±4,096V |
1 бит = 0,125mV |
|
3 |
2 |
±2,048V |
1 бит = 0,0625mV |
|
4 |
4 |
±1,024V |
1 бит = 0.03125mV |
|
5 |
8 |
±0,512V |
1 бит =0.015625mV |
|
6 |
16 |
±0,256V |
1 бит = 0,0078125mV |
Технические характеристики ADS115
Напряжение питания: 2V – 5,5V;
Минимальное потребление тока: 150 мкА;
Разрешение: 16 бит;
Тип интерфейса: I2C (адреса 0х48, 0х49, 0х4А, 0х4В);
Количество входов: 4 несимметричных или 2 дифференциальных;
Внутренний усилитель PGA: до х16;
Напряжение смещения: 100мкВ;
Настраиваемая скорость обработки данных: 8-860 выборок/сек.
Выходной программируемый компаратор;
Диапазон рабочих температур: -40ОС…+125ОС;
Тип корпусов микросхемы: X2QFN-10 или VSSOP-10;
Размер модуля: 28х16мм.
Подключение к плате Arduino
Подключить модуль к плате Arduino не составит никакого труда, так как все Arduino поддерживают интерфейс I2C. Программная работа с ADS1115 будет максимально эффективна при использовании специальной библиотеки, разработанной компанией «Adafruit».
Так как АЦП может работать в двух режимах (несимметричный и дифференциальный), схема измерительной цепи тоже будет иметь два варианта.
Несимметричный способ измерения
При использовании данного метода, в нашем распоряжении есть 4 канала, на каждом из которых измеряется напряжение относительно общего отрицательного провода микросхемы ADS1115. Следует учитывать, что при программировании параметров АЦП, последние будут действовать сразу для всех каналов, т.е. настроить разные коэффициенты усиления для каждого канала в частности не получиться. На рисунке №5 показана схема подключения АЦП ADS1115 к плате Arduino Nano с несимметричным режимом измерения.
Рисунок №5 – схема измерения 4-х напряжений
На вышеприведенном рисунке, в качестве примера, задействованы все 4 канала АЦП, а именно:
А0 – измеряет напряжение 5V, которое выдаёт Arduino Nano;
А1 – измеряет напряжение 3.3V, которое выдаёт Arduino Nano;
А2 – измеряет напряжение пальчиковой батарейки;
А3 – измеряет напряжение на LI-ION аккумуляторе.
Следует обратить внимание на то, что на вход ADS1115 будет поступать максимальное напряжение 5V. Следовательно, чтобы не превысить допустимый предел входного напряжения, нам необходимо выставить коэффициент усиления 2/3 (см. таблицу выше). Это даст возможность подавать на вход АЦП до 6.144V, что удовлетворяет требованиям всех 4-х измерительных точек. Ниже приведен скетч с подробными комментариями, с помощью которого все 4 измерения будут выводиться в монитор порта.
1. #include <Wire.h> // Библиотека для работы с шиной I2C
2. #include <Adafruit_ADS1015.h> // Библиотека для работы с модулями ADS1115 и ADS1015
3. Adafruit_ADS1115 ads; // Создание объекта ads для общения через него с модулем
4.
5. void setup() {
6. Serial.begin(9600); // Инициализация серийного порта
7.
8. // Установка коэффициента усиления 2/3
9. ads.setGain(GAIN_TWOTHIRDS);
10.
11. // ВОЗМОЖНЫЕ ВАРИАНТЫ УСТАНОВКИ КУ:
12. // ads.setGain(GAIN_TWOTHIRDS); | 2/3х | +/-6.144V | 1bit = 0.1875mV |
13. // ads.setGain(GAIN_ONE); | 1х | +/-4.096V | 1bit = 0.125mV |
14. // ads.setGain(GAIN_TWO); | 2х | +/-2.048V | 1bit = 0.0625mV |
15. // ads.setGain(GAIN_FOUR); | 4х | +/-1.024V | 1bit = 0.03125mV |
16. // ads.setGain(GAIN_EIGHT); | 8х | +/-0.512V | 1bit = 0.015625mV |
17. // ads.setGain(GAIN_SIXTEEN); | 16х | +/-0.256V | 1bit = 0.0078125mV |
18.
19. ads.begin(); // Инициализация модуля ADS1115
20. }
21.
22. void loop() {
23. // Переменные для хранения значений АЦП каждого канала
24. int16_t adc0, adc1, adc2, adc3;
25.
26. adc0 = ads.readADC_SingleEnded(0); // Чтение АЦП нулевого канала
27. adc1 = ads.readADC_SingleEnded(1); // Чтение АЦП первого канала
28. adc2 = ads.readADC_SingleEnded(2); // Чтение АЦП второго канала
29. adc3 = ads.readADC_SingleEnded(3); // Чтение АЦП третьего канала
30.
31. // Расчёт фактических напряжений на каждом канале
32. float u0 = float(adc0) * 0.1875 / 1000.0;
33. float u1 = float(adc1) * 0.1875 / 1000.0;
34. float u2 = float(adc2) * 0.1875 / 1000.0;
35. float u3 = float(adc3) * 0.1875 / 1000.0;
36.
37.
38. // Вывод значения АЦП и фактичесгого напряжения на каналах 0-3
39. Serial.print("ADC_AIN0="); Serial.print(adc0);
40. Serial.print(" VOLTAGE_AIN0="); Serial.print(u0); Serial.println("V");
41. Serial.print("ADC_AIN1="); Serial.print(adc0);
42. Serial.print(" VOLTAGE_AIN1="); Serial.print(u1); Serial.println("V");
43. Serial.print("ADC_AIN2="); Serial.print(adc0);
44. Serial.print(" VOLTAGE_AIN2="); Serial.print(u2); Serial.println("V");
45. Serial.print("ADC_AIN3="); Serial.print(adc0);
46. Serial.print(" VOLTAGE_AIN3="); Serial.print(u3); Serial.println("V");
47. Serial.println(" ");
48.
49. delay(1000);
50. }
Дифференциальный режим измерения
Преимуществом данного режима является возможность измерения разности напряжений между двумя точками. Такой подход целесообразен при мониторинге состояния отдельных элементов питания в составе общей батареи или когда необходимо узнать падение напряжения на токоизмерительном шунте. В общем, вариантов применения множество. Недостатком является тот факт, что вместо 4-х измерительных каналов мы получаем всего два. На рисунке №6 приведена схема подключения ADS1115 к плате Arduino Nano с использованием диф-режима. В данном примере выполняется измерение напряжения на АКБ и падение на резисторе для определения тока потребления электромотора.
Рисунок №6 – подключение ADS1115 к Arduino Nano (дифференциальный режим)
Следует отметить, что теперь нет необходимости соединять отрицательные провода цепи измерения с общим проводом Arduino Nano. Таким образом, мы получили нечто похожее на бытовой мультиметр. Ниже приведен скетч с подробными комментариями, реализующий измерения в дифференциальном режиме.
1. #include <Wire.h> // Библиотека для работы с шиной I2C
2. #include <Adafruit_ADS1015.h> // Библиотека для работы с модулями ADS1115 и ADS1015
3. Adafruit_ADS1115 ads; // Создание объекта ads для общения через него с модулем
4.
5. void setup() {
6. Serial.begin(9600); // Инициализация серийного порта
7.
8. // Установка коэффициента усиления 2/3
9. ads.setGain(GAIN_TWOTHIRDS);
10.
11. // ВОЗМОЖНЫЕ ВАРИАНТЫ УСТАНОВКИ КУ:
12. // ads.setGain(GAIN_TWOTHIRDS); | 2/3х | +/-6.144V | 1bit = 0.1875mV |
13. // ads.setGain(GAIN_ONE); | 1х | +/-4.096V | 1bit = 0.125mV |
14. // ads.setGain(GAIN_TWO); | 2х | +/-2.048V | 1bit = 0.0625mV |
15. // ads.setGain(GAIN_FOUR); | 4х | +/-1.024V | 1bit = 0.03125mV |
16. // ads.setGain(GAIN_EIGHT); | 8х | +/-0.512V | 1bit = 0.015625mV |
17. // ads.setGain(GAIN_SIXTEEN); | 16х | +/-0.256V | 1bit = 0.0078125mV |
18.
19. ads.begin(); // Инициализация модуля ADS1115
20. }
21.
22. void loop() {
23. int16_t adc_01_voltage; // Переменная для хранения значения АЦП вольтметра (канал 0-1)
24. int16_t adc_23_current; // Переменная для хранения значения АЦП амперметра (канал 2-3)
25.
26. adc_01_voltage = ads.readADC_Differential_0_1(); // Измеряем значение АЦП на канало 0-1
27. adc_23_current = ads.readADC_Differential_2_3(); // Измеряем значение АЦП на канало 2-3
28.
29. // Расчёт напряжения
30. float u = float(adc_01_voltage) * 0.1875 / 1000.0;
31.
32. // Расчёт падения напряжения на токоизмерительном резисторе 1 Ом
33. float ur = float(adc_23_current) * 0.1875 / 1000.0;
34. // Расчёт силы тока
35. float i = ur / 1.0; // Сопротивление резистора 1 Ом.
36.
37. // Вывод полученных значений в монитор серийного порта
38. Serial.print("VOLTAGE="); Serial.print(u); Serial.println("V");
39. Serial.print("CURRENT="); Serial.print(i); Serial.println("A");
40.
41. delay(1000);
42. }
Если во время проведения измерений на каналах 0-1 и 2-3 поменять местами провода, то будут получены отрицательные значения, сродни тем, которые получаются при неправильном подключении вольтметра. По умолчанию на каналы 0 и 2 должен поступать положительный полюс, а на каналы 1 и 3 – отрицательный.
Использование компаратора
Иногда в практике радиолюбителя появляется необходимость мониторинга пороговых значений по напряжению. Например, отслеживание окончания заряда аккумулятора и т.п. Модуль ADS1115 предоставляет удобную возможность реализации подобной задачи с помощью встроенного компаратора, который при срабатывании подаёт сигнал на вывод ALRT. В качестве примера, на рисунке №7 приведена схема, наглядно демонстрирующая работу компаратора.
Рисунок №7 – пример использования компаратора
Суть схемы в следующем. Пользователь вращает потенциометр, тем самым меняя значение напряжения от 0 до 5V на входе AIN0 модуля ADS1115. Программа задаёт порог срабатывания компаратора в 1,875V. Светодиод, подключенный к выходу ALRT компаратора, сигнализирует о превышении выставленного порога. Ниже приведён соответствующий скетч.
1. #include <Wire.h> // Библиотека для работы с шиной I2C
2. #include <Adafruit_ADS1015.h> // Библиотека для работы с модулями ADS1115 и ADS1015
3. Adafruit_ADS1115 ads; // Создание объекта ads для общения через него с модулем
4.
5. void setup(void)
6. {
7. Serial.begin(9600); // Инициализация серийного порта
8.
9. // Установка коэффициента усиления 2/3
10. ads.setGain(GAIN_TWOTHIRDS);
11.
12. // ВОЗМОЖНЫЕ ВАРИАНТЫ УСТАНОВКИ КУ:
13. // ads.setGain(GAIN_TWOTHIRDS); | 2/3х | +/-6.144V | 1bit = 0.1875mV |
14. // ads.setGain(GAIN_ONE); | 1х | +/-4.096V | 1bit = 0.125mV |
15. // ads.setGain(GAIN_TWO); | 2х | +/-2.048V | 1bit = 0.0625mV |
16. // ads.setGain(GAIN_FOUR); | 4х | +/-1.024V | 1bit = 0.03125mV |
17. // ads.setGain(GAIN_EIGHT); | 8х | +/-0.512V | 1bit = 0.015625mV |
18. // ads.setGain(GAIN_SIXTEEN); | 16х | +/-0.256V | 1bit = 0.0078125mV |
19.
20. ads.begin(); // Инициализация модуля ADS1115
21.
22. // Настраиваем компаратор на нулевом канале
23. // Так как исходя из установленного КУ 1 бит равен 0.1875mV, то для настройки
24. // компаратора на порог 1.875V нам это значение необходимо увеличить в 10000 раз.
25. // 0.1875mV = 0.0001875V
26. // 0.0001875V * 10000 = 1.875V
27. ads.startComparator_SingleEnded(0, 10000); // Установка порога 1.875V
28. }
29.
30. void loop(void)
31. {
32. int16_t adc0; // Переменная для чтения АЦП на нулевом канале
33. // Компаратор начнёт свою работу после чтения входного уровня
34. adc0 = ads.getLastConversionResults();
35. delay(100);
36. }
Измерение напряжений, превышающих максимальный порог ADS1115
В вышеприведенных примерах все входные напряжения не превышали допустимый входной порог модуля ADS1115, равный 6.144V. В реальных радиолюбительских конструкциях чаще всего приходится измерять гораздо большее напряжение, что однозначно выведет ADS1115 из строя.
Решить подобную проблему можно с помощью резистивного делителя, который преобразует высокое входное напряжение в приемлемое. В самой программе, для получения реального результата, потребуется умножить рассчитанное значение напряжения на коэффициент деления резистивного делителя. На рисунке №8 приведена классическая схема делителя напряжения, выполненная на двух резисторах.
Рисунок №8 – схема резистивного делителя
В качестве примера, разберём ситуацию, когда необходимо измерять напряжение до 25V. При этом настройка коэффициента усиления ADS1115 будет задана таким образом, чтобы максимальное входное напряжение не превышало 6.144V. Следовательно, необходимо рассчитать резистивный делитель, который преобразует 25V на его входе, в 6.144V на выходе. Сделать это можно на бумаге, затратив некоторое количество времени, но гораздо удобнее использовать онлайн калькулятор.
В ходе расчётов получились следующие значения:
Максимальное напряжение на входе резистивного делителя – 25.05V;
Резистор верхнего плеча R1 – 120k;
Резистор верхнего плеча R2 – 39k;
Выходное напряжение (при Uвх.= 25.05V) – 6,144V.
Подставим значения в формулу для проверки:
U2 = 25.05 * (39 / (120 + 39)) = 25.05 * (39 / 159) = 25.05 * 0.245283 = 6.144V
На рисунке №9 приведена схема подключения ADS1115 к плате Arduino Nano с применением резистивного делителя напряжения.
Рисунок №9 – Схема измерения напряжения с резистивным делителем
Ниже приведён текст программы, позволяющий выполнить расчёт измеренного напряжения исходя из вышеуказанного диапазона:
1. #include <Wire.h> // Библиотека для работы с шиной I2C
2. #include <Adafruit_ADS1015.h> // Библиотека для работы с модулями ADS1115 и ADS1015
3. Adafruit_ADS1115 ads; // Создание объекта ads для общения через него с модулем
4.
5. void setup() {
6. Serial.begin(9600); // Инициализация серийного порта
7. // Установка коэффициента усиления 2/3
8. ads.setGain(GAIN_TWOTHIRDS);
9. // ВОЗМОЖНЫЕ ВАРИАНТЫ УСТАНОВКИ КУ:
10. // ads.setGain(GAIN_TWOTHIRDS); | 2/3х | +/-6.144V | 1bit = 0.1875mV |
11. // ads.setGain(GAIN_ONE); | 1х | +/-4.096V | 1bit = 0.125mV |
12. // ads.setGain(GAIN_TWO); | 2х | +/-2.048V | 1bit = 0.0625mV |
13. // ads.setGain(GAIN_FOUR); | 4х | +/-1.024V | 1bit = 0.03125mV |
14. // ads.setGain(GAIN_EIGHT); | 8х | +/-0.512V | 1bit = 0.015625mV |
15. // ads.setGain(GAIN_SIXTEEN); | 16х | +/-0.256V | 1bit = 0.0078125mV |
16. ads.begin(); // Инициализация модуля ADS1115
17. }
18.
19. void loop() {
20. int16_t adc0 = ads.readADC_SingleEnded(0); // Чтение АЦП нулевого канала
21. float u = float(adc0) * 0.1875 / 1000.0; // Расчёт напряжения на входе нулевого канала после резистивного делителя
22. u = u * 25.05 / 6.144; // Расчёт фактического напряжения с учётом резистивного делителя
23. // Вывод фактического напряжения на нулевом канале
24. Serial.print("U="); Serial.print(u); Serial.println("V");
25. delay(1000);
26. }
Пример использования ADS1115
С целью закрепления материала, создадим проект регулируемого блока питания 0-24V 2A с функцией измерения напряжения и тока, значения которых будут выводиться на 7-сегментный индикатор. Для этого понадобятся следующие элементы:
Модуль ADS1115;
Модуль DC-DC преобразователя LM2596;
Переменный резистор 10k.
8-ми разрядный 7-сегментный индикатор с общим катодом и двумя микросхемами 74HC595;
Любой источник постоянного напряжения 24V (в моём случае БП от старого принтера);
Линейный стабилизатор L7805;
Плата Arduino Pro Mini.
Два постоянных резистора 120k и 39k для делителя напряжения;
Резистор 0.47 Ohm 5W для измерения силы тока;
На рисунке №10 приведена электрическая схема блока питания.
Рисунок №10 – схема блока питания
Для удобства регулировки напряжения на модуле LM2596 подстроечный резистор заменён на выносной переменный. Программный код для блока питания приведён ниже.
1. #include <Wire.h> // Библиотека для работы с шиной I2C
2. #include <Adafruit_ADS1015.h> // Библиотека для работы с модулями ADS1115 и ADS1015
3. Adafruit_ADS1115 ads; // Создание объекта ads для общения через него с модулем
4.
5. #define pinSH_CP 9 // Тактовые импульсы (sclk)
6. #define pinST_CP 8 // Защёлка (rclk)
7. #define pinDS 7 // Данные (dio)
8.
9. // Коды цифр для индикатора (без точек)
10. uint8_t symbolNP[11] = {192, 249, 164, 176, 153, 146, 130, 248, 128, 144, 127}; // 0, 1, 2, 3, 4, 5, 6, 7, 8, 9
11.
12. // Коды цифр для индикатор (с точками)
13. uint8_t symbolP[11] = {64, 121, 36, 48, 25, 18, 2, 120, 0, 16};
14.
15. // Массив числовых значений, указывающих адрес разряда индикатора
16. uint8_t segmentNumber[] = {0b10000000,
17. 0b01000000,
18. 0b00100000,
19. 0b00010000,
20. 0b00001000,
21. 0b00000100,
22. 0b00000010,
23. 0b00000001};
24.
25. uint8_t du[3] = {0, 0, 0}; // Массив для вывода напряжения на индикаторе
26. uint8_t di[4] = {0, 0, 0, 0}; // Массив для вывода силы тока на индикаторе
27. uint8_t globalState = 0; // Глобальное состояние системы
28. uint32_t timer = 0; // Пользовательский таймер
29.
30. int16_t adc_u; // Переменная для хранения АЦП напряжения
31. uint32_t adc_u_sum; // Переменная для суммы 8-ми измерений АЦП напряжения
32. int16_t adc_i; // Переменная для хранения АЦП силы тока
33. uint32_t adc_i_sum; // Переменная для суммы 8-ми измерений АЦП силы тока
34.
35.
36. // ФУНКЦИЯ ВЫВОДА НАПРЯЖЕНИЯ И СИЛЫ ТОКА НА ИНДИКАТОРЕ
37. void indicatorShowUI() {
38. digitalWrite(pinST_CP, LOW);
39. shiftOut(pinDS, pinSH_CP, MSBFIRST, symbolNP[ du[0] ]);
40. shiftOut(pinDS, pinSH_CP, LSBFIRST, segmentNumber[7]);
41. digitalWrite(pinST_CP, HIGH);
42.
43. digitalWrite(pinST_CP, LOW);
44. shiftOut(pinDS, pinSH_CP, MSBFIRST, symbolP[ du[1] ]);
45. shiftOut(pinDS, pinSH_CP, LSBFIRST, segmentNumber[6]);
46. digitalWrite(pinST_CP, HIGH);
47.
48. digitalWrite(pinST_CP, LOW);
49. shiftOut(pinDS, pinSH_CP, MSBFIRST, symbolNP[ du[2] ]);
50. shiftOut(pinDS, pinSH_CP, LSBFIRST, segmentNumber[5]);
51. digitalWrite(pinST_CP, HIGH);
52.
53. digitalWrite(pinST_CP, LOW);
54. shiftOut(pinDS, pinSH_CP, MSBFIRST, symbolNP[ di[0] ]);
55. shiftOut(pinDS, pinSH_CP, LSBFIRST, segmentNumber[3]);
56. digitalWrite(pinST_CP, HIGH);
57.
58. digitalWrite(pinST_CP, LOW);
59. shiftOut(pinDS, pinSH_CP, MSBFIRST, symbolNP[ di[1] ]);
60. shiftOut(pinDS, pinSH_CP, LSBFIRST, segmentNumber[2]);
61. digitalWrite(pinST_CP, HIGH);
62.
63. digitalWrite(pinST_CP, LOW);
64. shiftOut(pinDS, pinSH_CP, MSBFIRST, symbolNP[ di[2] ]);
65. shiftOut(pinDS, pinSH_CP, LSBFIRST, segmentNumber[1]);
66. digitalWrite(pinST_CP, HIGH);
67.
68. digitalWrite(pinST_CP, LOW);
69. shiftOut(pinDS, pinSH_CP, MSBFIRST, symbolNP[ di[3] ]);
70. shiftOut(pinDS, pinSH_CP, LSBFIRST, segmentNumber[0]);
71. digitalWrite(pinST_CP, HIGH);
72. }
73.
74. void setup() {
75. pinMode(pinSH_CP, OUTPUT);
76. pinMode(pinST_CP, OUTPUT);
77. pinMode(pinDS, OUTPUT);
78. analogReference(INTERNAL);
79.
80. // Установка коэффициента усиления 2/3
81. ads.setGain(GAIN_TWOTHIRDS);
82. // ВОЗМОЖНЫЕ ВАРИАНТЫ УСТАНОВКИ КУ:
83. // ads.setGain(GAIN_TWOTHIRDS); | 2/3х | +/-6.144V | 1bit = 0.1875mV |
84. // ads.setGain(GAIN_ONE); | 1х | +/-4.096V | 1bit = 0.125mV |
85. // ads.setGain(GAIN_TWO); | 2х | +/-2.048V | 1bit = 0.0625mV |
86. // ads.setGain(GAIN_FOUR); | 4х | +/-1.024V | 1bit = 0.03125mV |
87. // ads.setGain(GAIN_EIGHT); | 8х | +/-0.512V | 1bit = 0.015625mV |
88. // ads.setGain(GAIN_SIXTEEN); | 16х | +/-0.256V | 1bit = 0.0078125mV |
89. ads.begin(); // Инициализация модуля ADS1115
90. }
91.
92. void loop() {
93. while(1) {
94.
95. if(globalState == 0) {
96. // Выполняем 8 замеров АЦП напряжения и тока
97. for(uint8_t i = 0; i < 8; i++) {
98. adc_u_sum += ads.readADC_SingleEnded(0);
99. adc_i_sum += ads.readADC_SingleEnded(1);
100. }
101. // Вычисляем средние значения АЦП напряжения и тока
102. adc_u = adc_u_sum >> 3;
103. adc_i = adc_i_sum >> 3;
104.
105. adc_u_sum = 0;
106. adc_i_sum = 0;
107.
108. // Расчёт напряжения (для удобства вывода на индикатор, увеличиваем в 10 раз)
109. uint32_t u = map(adc_u, 0, 32768, 0, 250);
110. // Преобразование значения напряжения для вывода его на индикатор в формате XX.X
111. du[0] = u / 100; // Десятки Вольт
112. du[1] = (u % 100 - u % 10) / 10; // Единицы Вольт
113. du[2] = u % 10; // Десятые доли Вольта
114.
115. // Расчёт силы тока (для удобства вывода на индикатор, переводим в миллиамперы)
116. uint32_t i = map(adc_i, 0, 32768, 0, 1307); // (I=U/R =6.144/0.47=1307)
117. // Преобразование значения силы тока для вывода его на индикатор в формате XXXX
118. di[0] = i / 1000;
119. di[1] = (i % 1000 - i % 100) / 100;
120. di[2] = (i % 100 - i % 10) / 10;
121. di[3] = i % 10;
122.
123. timer = millis();
124. globalState = 1;
125. }
126. // Вывод значений с периодом 2 раза в секунду
127. else if(globalState == 1) {
128. if((millis() - timer) > 500) globalState = 0;
129. }
130. indicatorShowUI();
131. }
132. }
При изготовлении блока питания оказалось, что у моего индикатора неисправен 3-й разряд слева, поэтому десятую долю вольта я перенёс на четвёртый разряд, а третий просто оставил погасшим. В приведённой выше программе все разряды прописаны как надо. В итоге получился быстрый в изготовлении и очень удобный регулируемый блок питания, который 100% пригодится каждому радиолюбителю.
FAQ. Часто задаваемые вопросы
1. Как из среды Arduino IDE работать сразу с несколькими модулями ADS1115?
Ответ. Для начала необходимо задать разные адреса для каждого модуля (максимум 4 шт.). Сделать это можно ориентируясь на рисунок №3. Далее в программе необходимо создать для каждого модуля свой экземпляр класса с указанием адреса и в последствии работать с каждым из них:
1. #include <Wire.h>
2. #include <Adafruit_ADS1015.h>
3. Adafruit_ADS1115 ads1(0x48);
4. Adafruit_ADS1115 ads2(0x49);
5. Adafruit_ADS1115 ads1(0x4B);
6. Adafruit_ADS1115 ads1(0x4A);
7.
8. void setup() {
9. ads1.setGain(GAIN_TWOTHIRDS);
10. ads2.setGain(GAIN_TWOTHIRDS);
11. ads3.setGain(GAIN_TWOTHIRDS);
12. ads4.setGain(GAIN_TWOTHIRDS);
13. ads1.begin();
14. ads2.begin();
15. ads3.begin();
16. ads4.begin();
17. }
18.
19. void loop() {
20. ads1.readADC_SingleEnded(0);
21. ads3.readADC_SingleEnded(3);
22. // и т.д.......
23. }
2. Как изменить частоту дискретизации через регистры модуля?
Ответ. Частоту дискретизации можно изменить путём выбора значения в конфигурационном регистре, который имеет адрес 0x01. В данном регистре за частоту отвечают биты 7-5. Их значение и соответствующая частота отражены в таблице ниже
|
Конфигурационный регистр (адрес 0x01) |
|||
|
БИТ №7 |
БИТ №6 |
БИТ №5 |
Частота дискретизации |
|
0 |
0 |
0 |
8 Гц |
|
0 |
0 |
1 |
16 Гц |
|
0 |
1 |
0 |
32 Гц |
|
0 |
1 |
1 |
64 Гц |
|
1 |
0 |
0 |
128 Гц (частота по умолчанию) |
|
1 |
0 |
1 |
250 Гц |
|
1 |
1 |
0 |
475 Гц |
|
1 |
1 |
1 |
860 Гц |
3. Почему АЦП ADS1115 при чтении выдаёт максимальное значение 32768, а не 65535, как положено для 16 бит?
Ответ. Дело в том, что АЦП выдаёт знаковое 16-битное значение, поэтому максимальное показание будет 32768, а не 65535. Получить все 65535 значений получиться только в дифференциальном режиме при условии, когда на один из выводов будет подан источник опорного напряжения, а второй вывод будет являться измерительным.
4. Насколько сильно ADS1115 боится перенапряжения?
Ответ. Модуль довольно
чувствителен к перенапряжению как по питанию, так и по входам. Вероятность
выхода его из строя очень высока, если напряжение будет превышено более чем на 5%
от допустимого.